TITLE:	Configural Invariance for dichotomous items
    See Millsap & Tein (2004, p.485) for further details 
DATA:	FILE IS example2c.csv;
VARIABLE:	NAMES ARE u1-u8 g;
    USEVARIABLES ARE u1-u8;
	CATEGORICAL ARE u1-u8;
	GROUPING IS g (1=male 2=female);
! Theta parameterization is strongly recommended for multiple groups
ANALYSIS: PARAMETERIZATION = THETA; ESTIMATOR = WLSMV;
MODEL:
    ! Factor loadings are free except the marker variables
    f1 BY u1@1 u2 u3 u4;
    f2 BY u5@1 u6 u7 u8;
        	
    ! Thresholds are constrained across groups
    [u1$1] (t1);
    [u2$1] (t2);
    [u3$1] (t3);
    [u4$1] (t4);
    [u5$1] (t5);
    [u6$1] (t6);
    [u7$1] (t7);
    [u8$1] (t8);

    ! Factor variance/covariance are free across groups
    f1*; f2*;
    f1 WITH f2*;

    ! Factor mean of the first group are fixed to zeros
    [f1@0];
    [f2@0];

    ! Unique variances of the all groups are fixed as 1
    u1@1;
    u2@1;
    u3@1;
    u4@1;
    u5@1;
    u6@1;
    u7@1;
    u8@1;

MODEL female: 
    ! Factor loadings are free except the marker variables
    f1 BY u1@1 u2 u3 u4;
    f2 BY u5@1 u6 u7 u8;
   
    ! Thresholds are constrained across groups
    [u1$1] (t1);
    [u2$1] (t2);
    [u3$1] (t3);
    [u4$1] (t4);
    [u5$1] (t5);
    [u6$1] (t6);
    [u7$1] (t7);
    [u8$1] (t8);

    ! Factor variance/covariance are free across groups
    f1*; f2*;
    f1 WITH f2*;

    ! Factor mean of the second group are free
    [f1*];
    [f2*];

    ! Unique variances of the marker variables are fixed but others are free.
    u1@1;
    u2*;
    u3*;
    u4*;
    u5@1;
    u6*;
    u7*;
    u8*;
OUTPUT: TECH1; STDYX;
! Save the chi-square values for difference testing with other nested models
SAVEDATA: DIFFTEST=configural2c.dif;