TITLE:	Strict Invariance for dichotomous items
    See Millsap & Tein (2004, p.485) for further details 
DATA:	FILE IS example2c.csv;
VARIABLE:	NAMES ARE u1-u8 g;
    USEVARIABLES ARE u1-u8;
	CATEGORICAL ARE u1-u8;
	GROUPING IS g (1=male 2=female);
! Theta parameterization is strongly recommended for multiple groups
ANALYSIS: PARAMETERIZATION = THETA; ESTIMATOR = WLSMV;
! Put the chi-square values of the model that we wish to compare with this model
    DIFFTEST=weak2c.dif; ! strict vs. weak
MODEL:
    ! Factor loadings are constrained across groups 
    ! except the marker variables, which are fixed.
    f1 BY u1@1 
        u2 (f21)
        u3 (f31)
        u4 (f41);
    f2 BY u5@1 
        u6 (f62)
        u7 (f72)
        u8 (f82);
        	
    ! Thresholds are constrained across groups
    [u1$1] (t1);
    [u2$1] (t2);
    [u3$1] (t3);
    [u4$1] (t4);
    [u5$1] (t5);
    [u6$1] (t6);
    [u7$1] (t7);
    [u8$1] (t8);

    ! Factor variance/covariance are free across groups
    f1*; f2*;
    f1 WITH f2*;

    ! Factor mean of the first group are fixed to zeros
    [f1@0];
    [f2@0];

    ! Unique variances of the all groups are fixed as 1
    u1@1;
    u2@1;
    u3@1;
    u4@1;
    u5@1;
    u6@1;
    u7@1;
    u8@1;

MODEL female: 
    ! Factor loadings are constrained across groups 
    ! except the marker variables, which are fixed.
    f1 BY u1@1 
        u2 (f21)
        u3 (f31)
        u4 (f41);
    f2 BY u5@1 
        u6 (f62)
        u7 (f72)
        u8 (f82);
   
    ! Thresholds are constrained across groups
    [u1$1] (t1);
    [u2$1] (t2);
    [u3$1] (t3);
    [u4$1] (t4);
    [u5$1] (t5);
    [u6$1] (t6);
    [u7$1] (t7);
    [u8$1] (t8);

    ! Factor variance/covariance are free across groups
    f1*; f2*;
    f1 WITH f2*;

    ! Factor mean of the second group are free
    [f1*];
    [f2*];

    ! Unique variances are fixed to 1 (equal to the first group)
    u1@1;
    u2@1;
    u3@1;
    u4@1;
    u5@1;
    u6@1;
    u7@1;
    u8@1;
OUTPUT: TECH1; STDYX;
! Save the chi-square values for difference testing with other nested models
SAVEDATA: DIFFTEST=strict2c.dif;