TITLE:	Weak Invariance for 5-points Likert Items
    See Millsap & Tein (2004, p.485) for further details 
DATA:	FILE IS example5c.csv;
VARIABLE:	NAMES ARE u1-u8 g;
    USEVARIABLES ARE u1-u8;
	CATEGORICAL ARE u1-u8;
	GROUPING IS g (1=male 2=female);
ANALYSIS: PARAMETERIZATION = THETA; ESTIMATOR = WLSMV;
! Put the chi-square values of the model that we wish to compare with this model
    DIFFTEST=configural5c.dif; ! weak vs. configural
MODEL:
    ! Factor loadings are constrained across groups 
    ! except the marker variables, which are fixed.
    f1 BY u1@1 
        u2 (f21)
        u3 (f31)
        u4 (f41);
    f2 BY u5@1 
        u6 (f62)
        u7 (f72)
        u8 (f82);
        	
    ! One threshold in each item are constrained across groups
    ! One additional threshold in the marker variable are constrained across groups
    [u1$1] (t11);
    [u1$2] (t12);
    [u1$3];
    [u1$4];
    [u2$1] (t21);
    [u2$2];
    [u2$3];
    [u2$4];
    [u3$1] (t31);
    [u3$2];
    [u3$3];
    [u3$4];
    [u4$1] (t41);
    [u4$2];
    [u4$3];
    [u4$4];
    [u5$1] (t51);
    [u5$2] (t52);
    [u5$3];
    [u5$4];
    [u6$1] (t6);
    [u6$2];
    [u6$3];
    [u6$4];
    [u7$1] (t7);
    [u7$2];
    [u7$3];
    [u7$4];
    [u8$1] (t8);
    [u8$2];
    [u8$3];
    [u8$4];

    ! Factor variance/covariance are free across groups
    f1*; f2*;
    f1 WITH f2*;

    ! Factor mean of the first group are fixed to zeros
    [f1@0];
    [f2@0];

    ! Unique variances of the all groups are fixed as 1
    u1@1;
    u2@1;
    u3@1;
    u4@1;
    u5@1;
    u6@1;
    u7@1;
    u8@1;

MODEL female: 
    ! Factor loadings are constrained across groups 
    ! except the marker variables, which are fixed.
    f1 BY u1@1 
        u2 (f21)
        u3 (f31)
        u4 (f41);
    f2 BY u5@1 
        u6 (f62)
        u7 (f72)
        u8 (f82);
   
    ! One threshold in each item are constrained across groups
    ! One additional threshold in the marker variable are constrained across groups
    [u1$1] (t11);
    [u1$2] (t12);
    [u1$3];
    [u1$4];
    [u2$1] (t21);
    [u2$2];
    [u2$3];
    [u2$4];
    [u3$1] (t31);
    [u3$2];
    [u3$3];
    [u3$4];
    [u4$1] (t41);
    [u4$2];
    [u4$3];
    [u4$4];
    [u5$1] (t51);
    [u5$2] (t52);
    [u5$3];
    [u5$4];
    [u6$1] (t6);
    [u6$2];
    [u6$3];
    [u6$4];
    [u7$1] (t7);
    [u7$2];
    [u7$3];
    [u7$4];
    [u8$1] (t8);
    [u8$2];
    [u8$3];
    [u8$4];


    ! Factor variance/covariance are free across groups
    f1*; f2*;
    f1 WITH f2*;

    ! Factor mean of the second group are free
    [f1*];
    [f2*];

    ! Unique variances are free in the second group.
    u1*;
    u2*;
    u3*;
    u4*;
    u5*;
    u6*;
    u7*;
    u8*;
OUTPUT: TECH1; STDYX;
! Save the chi-square values for difference testing with other nested models
SAVEDATA: DIFFTEST=weak5c.dif;